blob: 65260c6678ffe0bc7a0f546ae4eaf48f8ec42464 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Florian Maunier <fmauneko@dissidence.ovh>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Max Liebkies <mail@maxliebkies.de>
pkgbase=dotnet-core-preview
pkgname=('dotnet-host-preview' 'dotnet-runtime-preview' 'aspnet-runtime-preview' 'dotnet-sdk-preview')
pkgver=5.0.0+100+preview.3.20216.6
pkgrel=1
arch=('x86_64' 'armv7h' 'aarch64')
url='https://www.microsoft.com/net/core'
license=('MIT')
makedepends=(
'clang' 'cmake' 'curl' 'git' 'icu' 'krb5' 'libunwind' 'lldb' 'llvm'
'lttng-ust' 'openssl' 'zlib'
)
options=('staticlibs')
source=(
'dotnet.sh'
)
source_x86_64=(
'https://download.visualstudio.microsoft.com/download/pr/7ceba34e-5d50-4b23-b326-0a7d02b4decd/62dd73db9be67127a5645ef0efb0bba4/dotnet-sdk-5.0.100-preview.3.20216.6-linux-x64.tar.gz'
)
source_armv7h=(
'https://download.visualstudio.microsoft.com/download/pr/58276f20-1ff1-49e7-afbd-fcc6a20acf56/18aacff58da12a91e691036be7ef8063/dotnet-sdk-5.0.100-preview.3.20216.6-linux-arm.tar.gz'
)
source_aarch64=(
'https://download.visualstudio.microsoft.com/download/pr/67d8e63e-753d-4900-997f-b332bb63b025/303b7ac855985d077056ef4552f4a4e9/dotnet-sdk-5.0.100-preview.3.20216.6-linux-arm64.tar.gz'
)
sha256sums=('4978b3a31a94032b425d2a2a9b5a17f506f36fb784fbfefdf2cfea9485a30f47')
sha256sums_x86_64=('7742a0e9e562d711ef075f596115e4a5c68611f17ad7118b615cda8e250d1d82')
sha256sums_armv7h=('4334b0d8c901660303607940aca40c7f933aaeaf393dc1fbbc3e9c25e7136090')
sha256sums_aarch64=('336551db29a8f2c677e0d18a9e8ee213069277b1b5ae210296f3497f10f9da23')
package_dotnet-host-preview() {
pkgdesc='A generic driver for the .NET Core Command Line Interface (preview)'
provides=("dotnet-host=${pkgver%+*}")
conflicts=('dotnet-host')
install -dm 755 "${pkgdir}"/{opt/dotnet,usr/share/licenses/dotnet-host-preview}
cp -dr --no-preserve='ownership' dotnet host "${pkgdir}"/opt/dotnet/
cp -dr --no-preserve='ownership' LICENSE.txt ThirdPartyNotices.txt "${pkgdir}"/usr/share/licenses/dotnet-host-preview
install -Dm 755 "${srcdir}"/dotnet.sh "${pkgdir}"/usr/bin/dotnet
}
package_dotnet-runtime-preview() {
pkgdesc='The .NET Core runtime (preview)'
depends=('dotnet-host-preview' 'icu' 'krb5' 'libunwind' 'openssl' 'zlib'
'libcurl.so')
optdepends=('lttng-ust: CoreCLR tracing')
provides=("dotnet-runtime=${pkgver%+*}")
install -dm 755 "${pkgdir}"/{opt/dotnet/shared,usr/share/licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.NETCore.App "${pkgdir}"/opt/dotnet/shared/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/dotnet-runtime-preview
}
package_aspnet-runtime-preview() {
pkgdesc='The ASP.NET Core runtime (preview)'
depends=('dotnet-runtime-preview')
provides=("aspnet-runtime=${pkgver%+*}")
install -dm 755 "${pkgdir}"/{opt/dotnet/shared,usr/share/licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.AspNetCore.App "${pkgdir}"/opt/dotnet/shared/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/aspnet-runtime-preview
}
package_dotnet-sdk-preview() {
pkgdesc='The .NET Core SDK (preview)'
depends=('dotnet-runtime-preview')
provides=("dotnet-sdk=${pkgver%+*}")
install -dm 755 "${pkgdir}"/{opt/dotnet,usr/share/licenses}
cp -dr --no-preserve='ownership' packs sdk templates "${pkgdir}"/opt/dotnet/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/dotnet-sdk-preview
}
# vim: ts=2 sw=2 et:
|