PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

# Maintainer: Arti Zirk <arti@zirk.me>
# Maintainer: ndom91
# Contributor: Drata
# Contributor: otaj

_pkgname="Drata Agent"
pkgname=drata-agent
pkgver=3.7.0
pkgrel=1
pkgdesc="The Drata Agent is a light-weight tray-application that runs in the background, reporting important read-only data to Drata about your machine’s state for compliance tracking."
arch=('x86_64')
url="https://github.com/drata/drata-agent"
license=("Apache-2.0")
depends=('electron')
optdepends=('libappindicator-gtk3: systray indicator')
makedepends=('asar')
options=('!strip' '!emptydirs')
source=("drata-agent")
source_x86_64=("${pkgname}-${pkgver}.deb::https://github.com/drata/agent-releases/releases/download/v${pkgver}/Drata-Agent-linux.deb")
sha512sums=('0f692de3645f30c9925a61e3a6044270f6ec662fb2ba654ed9902bd491b4ed7a54572b212bf4a3eee3f856c0ec1c28a59309a67652a1bb006c65c8ca70cd6bac')
sha512sums_x86_64=('5765c846bb7ca454a5dc13427b9fd8fa21d4b2972e2983f891b1d3c2baba5ac332260ff041d3e1a10ddd353a858a03ee93b1bd3c0ded276d2f9ebd68ef1ca927')

prepare() {
	## Extract archive
	install -dm755 $pkgname-$pkgver
	tar -xJC $pkgname-$pkgver -f data.tar.xz

	pushd "$pkgname-$pkgver"

	## Use system electron via wrapper
	sed -i 's|^Exec=.*$|Exec=/usr/bin/drata-agent %U|' usr/share/applications/$pkgname.desktop

	# workaround for https://github.com/electron/electron/issues/31121
	asar extract opt/"$_pkgname"/resources/app.asar app
	sed -i "s#process\.resourcesPath#'/usr/lib/$pkgname'#g" app/dist/main.js
	asar pack app opt/"$_pkgname"/resources/app.asar

	popd
}


package() {
	cd "$srcdir"/$pkgname-$pkgver

	## Main electron app bundle
	install -D -m644 opt/"$_pkgname"/resources/app.asar "$pkgdir"/usr/lib/$pkgname/app.asar
	install -D -m755 "$srcdir"/drata-agent "$pkgdir"/usr/bin/drata-agent

	## Install included osquery binary
	install -D -m755 opt/"$_pkgname"/resources/lib/linux/bin/osqueryi "$pkgdir"/usr/lib/$pkgname/lib/linux/bin/osqueryi
	### TODO: Could we replace osqueryi binary with arch linux package?

	## Install additional stuff
	install -D -m644 usr/share/applications/$pkgname.desktop \
					"$pkgdir"/usr/share/applications/$pkgname.desktop

	## Install icons
	for size in 16 32 48 128 256 512 ; do
		install -D -m644 usr/share/icons/hicolor/${size}x${size}/apps/$pkgname.png \
						"$pkgdir"/usr/share/icons/hicolor/${size}x${size}/apps/$pkgname.png
	done
}