PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Maintainer: Dan Printzell <arch@vild.io>

pkgname=('dscanner-git')
pkgver=0.4.0.r73.0b064a0
pkgrel=2
pkgdesc="Swiss-army knife for D source code"
arch=('i686' 'x86_64')
url="https://github.com/dlang-community/D-Scanner"
license=("BSL")
groups=('dlang')
makedepends=('dmd' 'git')
depends=('libphobos')
provides=('dscanner')
conflicts=('dscanner')

source=(
	"git+https://github.com/dlang-community/D-Scanner"
	"git+https://github.com/Hackerpilot/libdparse"
	"git+https://github.com/burner/inifiled"
	"git+https://github.com/economicmodeling/containers"
	"git+https://github.com/Hackerpilot/dsymbol"
	"git+https://github.com/economicmodeling/libddoc"
)
sha256sums=(
	'SKIP'
	'SKIP'
	'SKIP'
	'SKIP'
	'SKIP'
	'SKIP'
)

pkgver() {
	cd "$srcdir/D-Scanner"
	git describe --long --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g;s/\.rc./rc/g'
}

prepare() {
	cd "$srcdir/D-Scanner"

	git submodule init
	git config submodule.libdparse.url "$srcdir/libdparse"
	git config submodule.inifiled.url "$srcdir/inifiled"
	git config submodule.containers.url "$srcdir/containers"
	git config submodule.dsymbol.url "$srcdir/dsymbol"
	git config submodule.libddoc.url "$srcdir/libddoc"
	git submodule update
}

build() {
	cd "$srcdir/D-Scanner"
	make
}

package() {
	# binaries
	install -Dm755 "$srcdir/D-Scanner/bin/dscanner" "$pkgdir/usr/bin/dscanner"

	# license
	install -Dm644 "$srcdir/D-Scanner/LICENSE_1_0.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}