blob: 67bda0e78997f80fc45e9f363c24e8cee65b3fff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Ian Young <ian at iangreenleaf dot com>
# Contributor: Gunnar Bretthauer <taijian@posteo.de>
pkgname=duplicacy
pkgver=3.2.3
pkgrel=2
pkgdesc="A new generation cloud backup tool based on lock-free deduplication"
arch=('x86_64' 'i686')
url="https://duplicacy.com/"
license=('custom')
depends=('glibc')
makedepends=('go' 'git')
source=("$pkgname-$pkgver.tar.gz::https://github.com/gilbertchen/$pkgname/archive/v$pkgver.tar.gz")
sha256sums=('8c8e30fb24a60e1a2c0cc11e0f408114163d6d911c7824000913fec88f31e32e')
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
prepare() {
cd "$pkgname-$pkgver/$pkgname"
mkdir -p "src/github.com/gilbertchen"
ln -sf "$srcdir/$pkgname-$pkgver" "src/github.com/gilbertchen/$pkgname"
GOPATH="$srcdir/$pkgname-$pkgver/$pkgname" go get -d -v
}
build() {
cd "$pkgname-$pkgver/$pkgname"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
GOPATH="$srcdir/$pkgname-$pkgver/$pkgname" go build -x
}
check() {
cd "$pkgname-$pkgver/$pkgname"
GOPATH="$srcdir/$pkgname-$pkgver/$pkgname" go test -v -x
}
package() {
cd "$pkgname-$pkgver"
install -Dm755 "$pkgname/$pkgname" "$pkgdir/usr/bin/$pkgname"
install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
}
|