blob: 88594d099c911ac86319afbe3322781761d57f2c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Lukas Grossar <lukas.grossar@gmail.com>
pkgname=dyff
pkgver=1.9.4
pkgrel=1
pkgdesc="Diff tool for YAML files"
arch=(x86_64)
url="https://github.com/homeport/${pkgname}"
license=(MIT)
depends=(glibc)
makedepends=(go)
source=(${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz)
sha256sums=('77e48f951de76636080bfe067293262a491fd7b26511b189c5c655cdb7c24516')
prepare() {
cd ${pkgname}-${pkgver}
mkdir -p build
go mod download
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd ${pkgname}-${pkgver}
go build -o build ./...
build/dyff completion bash >dyff.bash
build/dyff completion zsh >_dyff
build/dyff completion fish >dyff.fish
}
check() {
cd ${pkgname}-${pkgver}
go test ./...
}
package() {
cd ${pkgname}-${pkgver}
install -Dv build/dyff -t "$pkgdir/usr/bin"
install -Dvm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
install -Dvm644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
install -Dvm644 dyff.bash "$pkgdir/usr/share/bash-completion/completions/dyff"
install -Dvm644 _dyff -t "$pkgdir/usr/share/zsh/site-functions/"
install -Dvm644 dyff.fish -t "$pkgdir/usr/share/fish/vendor_completions.d/"
}
|