blob: 287c54421610650021e25503aedae2b2b409a757 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Junxuan Liao <mikeljx at 126 dot com>
pkgname=dynamorio
pkgdesc="A dynamic instrumentation tool platform"
pkgver=10.0.0
pkgrel=1
arch=('x86_64')
url="https://github.com/DynamoRIO/dynamorio"
license=('BSD' 'custom:libelftc' 'LGPL2.1')
groups=()
depends=('gcc-libs' 'zlib' 'libunwind' 'snappy' 'lz4' 'perl' 'qt5-base' 'python')
makedepends=('git' 'cmake' 'doxygen')
options=(!strip)
source=(
"${pkgname}::git+${url}.git#tag=release_${pkgver}"
"git+https://github.com/intel/libipt.git"
"git+https://github.com/madler/zlib.git"
)
sha256sums=('SKIP' 'SKIP' 'SKIP')
prepare() {
cd "${srcdir}/${pkgname}"
git submodule init
git config submodule.third_party/libipt.url "$srcdir/libipt"
git config submodule.third_party/zlib.url "$srcdir/zlib"
git -c protocol.file.allow=always submodule update
}
build() {
cmake -B build-debug -S "${srcdir}/${pkgname}" \
-DDEBUG=ON \
-DCMAKE_INSTALL_PREFIX="/opt/${pkgname}"
cmake --build build-debug
cmake -B build-release -S "${srcdir}/${pkgname}" \
-DCMAKE_INSTALL_PREFIX="/opt/${pkgname}"
cmake --build build-release
}
package() {
DESTDIR="$pkgdir" cmake --install build-debug
DESTDIR="$pkgdir" cmake --install build-release
install -Dm644 ${srcdir}/${pkgname}/License.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|