blob: 1be8b8ee80f23043e0de8049308fdaf235aec4e9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: "Jan Kohnert <bughunter@jan-kohnert.de"
# Contributor: Graziano Giuliani <graziano.giuliani@poste.it>
pkgname=eccodes
pkgver=2.41.0
_attnum=45757960
pkgrel=1
pkgdesc="ECMWF decoding library for GRIB, BUFR and GTS"
arch=("i686" "x86_64")
url="https://confluence.ecmwf.int/display/ECC/ecCodes+Home"
license=("Apache-2.0")
depends=("glibc" "gcc-libs" "libaec" "libpng" "openjpeg2" "netcdf")
makedepends=("gcc-fortran" "cmake")
optdepends=("bash" "ksh")
conflicts=("grib_api" "libbufr-ecmwf")
source=(
"${pkgname}-${pkgver}-Source.tar.gz::https://confluence.ecmwf.int/download/attachments/${_attnum}/${pkgname}-${pkgver}-Source.tar.gz?api=v2"
"${pkgname}-${pkgver}-test-data.tar.gz::https://get.ecmwf.int/repository/test-data/eccodes/eccodes_test_data.tar.gz"
)
sha512sums=(
"f2a8153bf3541445c59b49c3460a64bebd4c2d7201fd4bfe9b548f45d78b8215e0a1b37f87a9cdf0a338dabda4faafbaf5d31374df7c297846751469f9b7a5c6"
"8b4c7159dd7ed0e1e69068ec7dcabe94064f0d2abf9eac4fca2a9c730d500999e8edf1e7eeebba6fb12ae99b223c1b0843e31414538333c52f2508cb2d410151"
)
prepare() {
mkdir -p "$srcdir/${pkgname}-${pkgver}-Source/build"
if [ -d "$srcdir/${pkgname}-${pkgver}-Source/build/data" ]; then
rm -r "$srcdir/${pkgname}-${pkgver}-Source/build/data"
fi
mv data "$srcdir/${pkgname}-${pkgver}-Source/build/"
}
build() {
cd "$srcdir/${pkgname}-${pkgver}-Source/build"
cmake -DCMAKE_BUILD_TYPE=production -DCMAKE_INSTALL_DATADIR=/usr/share \
-DCMAKE_INSTALL_DATAROOTDIR=/usr/share/$pkgname/definitions \
-DCMAKE_INSTALL_PREFIX=/usr -DENABLE_AEC=ON \
-DENABLE_ECCODES_THREADS=ON -DENABLE_EXTRA_TESTS=ON -DENABLE_JPG=ON \
-DENABLE_JPG_LIBJASPER=OFF -DENABLE_JPG_LIBOPENJPEG=ON -DENABLE_PNG=ON ..
make
}
check() {
cd "$srcdir/${pkgname}-${pkgver}-Source/build"
make test
}
package() {
cd "$srcdir/${pkgname}-${pkgver}-Source/build"
make DESTDIR="$pkgdir" install
}
|