blob: a8a004f86d089c09839a8fca0e95e8f4ca74bac1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Mattia Moffa <mattia [at] moffa [dot] xyz>
pkgname=eclipse-cpp-bin
_pkgname=${pkgname%-bin}
epoch=2
pkgver=4.37
pkgrel=1
_release=2025-09/R
pkgdesc="Highly extensible IDE (C/C++ version)"
arch=('x86_64' 'aarch64')
url="https://www.eclipse.org/"
license=('EPL')
depends=('java-runtime>=21' webkit2gtk unzip)
makedepends=()
provides=(eclipse=$pkgver-$pkgrel)
conflicts=(eclipse)
options=(!strip)
_srcfilename_x86_64="$_pkgname-${_release//\//-}-linux-gtk-x86_64.tar.gz"
_srcfilename_aarch64="$_pkgname-${_release//\//-}-linux-gtk-aarch64.tar.gz"
source_x86_64=("$_srcfilename_x86_64::https://www.eclipse.org/downloads/download.php?file=/technology/epp/downloads/release/$_release/$_srcfilename_x86_64&r=1")
source_aarch64=("$_srcfilename_aarch64::https://www.eclipse.org/downloads/download.php?file=/technology/epp/downloads/release/$_release/$_srcfilename_aarch64&r=1")
sha512sums_x86_64=('8580df6a79af5e28bd46d8e84a5176be7fe794e53c4f445e806c6d4ea07a2cdc3423702f610d0531936ec8865f950ec018d7ee38321d30e0e91dfe6563b93679')
sha512sums_aarch64=('7ef9a5dbc135de5277b0b7403decb101c4bf2bc7d1410f22ad9c0cc22395d94f0416ec2e07bbdc07b2f2b86c17740f8f201cc934d242459819ab57eaf77fe6dc')
source=("eclipse.desktop")
sha512sums=('96a532509459056c470e18bc5fde639cd9725b831ff69864a444ed8282dd87aefe71b23be92280f22a480f2321794c4e3f7b8026925fb03625f0bb954a06e139')
#backup=('usr/lib/eclipse/eclipse.ini')
package() {
install -d "${pkgdir}/usr/lib"
cp -r "eclipse" "${pkgdir}/usr/lib/eclipse"
install -d "${pkgdir}/usr/bin"
ln -s "/usr/lib/eclipse/eclipse" "${pkgdir}/usr/bin/eclipse"
install -Dm644 "eclipse.desktop" "${pkgdir}/usr/share/applications/eclipse.desktop"
for i in 16 22 24 32 48 64 128 256 512 1024 ; do
install -Dm644 eclipse/plugins/org.eclipse.platform_${pkgver}*/eclipse$i.png \
"${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/eclipse.png"
done
}
|