blob: ac9b73aa6e2e06eb4c8c125bfb5c9e3d5f12b263 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Mattia Moffa <mattia [at] moffa [dot] xyz>
# Maintainer: Morgenstern <charles [at] charlesbwise [dot] com>
pkgname=eclipse-java-bin
_pkgname=${pkgname%-bin}
epoch=2
pkgver=4.36
pkgrel=1
_release=2025-06/R
pkgdesc="Highly extensible IDE (Java version)"
arch=('x86_64' 'aarch64')
url="https://www.eclipse.org/"
license=('EPL')
depends=('java-environment>=21'
'unzip'
'webkit2gtk')
provides=(eclipse=$pkgver-$pkgrel)
conflicts=(eclipse)
options=(!strip)
_srcfilename_x86_64="$_pkgname-${_release//\//-}-linux-gtk-x86_64.tar.gz"
_srcfilename_aarch64="$_pkgname-${_release//\//-}-linux-gtk-aarch64.tar.gz"
source_x86_64=("$_srcfilename_x86_64::https://www.eclipse.org/downloads/download.php?file=/technology/epp/downloads/release/$_release/$_srcfilename_x86_64&r=1")
source_aarch64=("$_srcfilename_aarch64::https://www.eclipse.org/downloads/download.php?file=/technology/epp/downloads/release/$_release/$_srcfilename_aarch64&r=1")
sha512sums_x86_64=('cad4bb830922e412703ce7b354780e03902e5297d786a2a86bcf058ac8a8a3e9dc04b058911a5850b8637a4b969aa4cd75e1ad13f4730921f34393bca6594e23')
sha512sums_aarch64=('08c383fa680146097b1cfb3281e335282405c2b2e823509cef686839848a88e5bed58bf8d4e5a71ee92e52740c405140c16fca5027e51fa6636305bd5c9dfcb1')
source=("eclipse.desktop")
sha512sums=('676d79e18ef847fc27efc68d85e5f3c3af3eaaa9946acc98161998a3a0771d2a72c7197bdb6d8c180e1b59c2a0bb591150d15114b416c1a0a0f5dbdb06bdb13e')
#backup=('usr/lib/eclipse/eclipse.ini')
package() {
install -d "${pkgdir}/usr/lib"
cp -r "eclipse" "${pkgdir}/usr/lib/eclipse"
install -d "${pkgdir}/usr/bin"
ln -s "/usr/lib/eclipse/eclipse" "${pkgdir}/usr/bin/eclipse"
install -Dm0644 "eclipse.desktop" "${pkgdir}/usr/share/applications/eclipse.desktop"
for i in 16 22 24 32 48 64 128 256 512 1024 ; do
install -Dm0644 eclipse/plugins/org.eclipse.platform_${pkgver}*/eclipse$i.png \
"${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/eclipse.png"
done
}
|