blob: ca8dab3a4c70d39d3ea0d0f5f60a2e17dc8dbc3b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Matthias Mailänder <matthias [at] mailaender [dot] name>
pkgname=eclipse-rcp
epoch=2
pkgver=4.32
pkgrel=1
_release=2024-06/R
pkgdesc="IDE for Rich Client Platform (RCP) and Remote Application Platform (RAP)"
arch=('x86_64')
url="https://eclipse.org/ide"
license=('EPL')
provides=(eclipse=$pkgver-$pkgrel)
conflicts=(eclipse)
_srcfilename="$pkgname-${_release//\//-}-linux-gtk-$CARCH.tar.gz"
source=("$_srcfilename::https://www.eclipse.org/downloads/download.php?file=/technology/epp/downloads/release/$_release/$_srcfilename&r=1"
"eclipse.desktop::https://raw.githubusercontent.com/Mailaender/org.eclipse.linuxtools.eclipse-build/patch-1/desktopintegration/eclipse.desktop")
sha512sums=('6ecbeb83220f382d8459de3fed9097c90a5c5d6e3a46c06681bf51e23524d6cd30e134022fac9e1de2a26233528236c86161a9d88090990bd444f210f1748561'
'824875ab1454349a58eb2bb6fd70edd5e7a8e14a9b999372024374a1e04722398095db9bdba91b17bfb424c1e1271446f0370c79596f35fb516dbada31aebec5')
backup=('usr/lib/eclipse/eclipse.ini')
package() {
install -d "${pkgdir}/usr/lib"
cp -r "eclipse" "${pkgdir}/usr/lib/eclipse"
install -d "${pkgdir}/usr/bin"
ln -s "/usr/lib/eclipse/eclipse" "${pkgdir}/usr/bin/eclipse"
install -Dm0644 "eclipse.desktop" "${pkgdir}/usr/share/applications/eclipse.desktop"
for i in 16 22 24 32 48 64 128 256 512 1024 ; do
install -Dm0644 eclipse/plugins/org.eclipse.platform_${pkgver}*/eclipse$i.png \
"${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/eclipse.png"
done
}
|