blob: 3d1e146052f8afde45bd572f73b1362096cb304a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Gilbert Gilb's <gilbsgilbert@gmail.com>
# Contributor: Vincent Grande <shoober420@gmail.com>
# Contributor: David Runge <dvzrv@archlinux.org>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Murtuza Akhtari <inxsible at gmail dot com>
# Contributor: Keshav Amburay <(the ddoott ridikulus ddoott rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>
pkgname=efibootmgr-json-git
pkgver=r392.g975051a
pkgrel=1
pkgdesc="Linux user-space application to modify the EFI Boot Manager with JSON support."
arch=('x86_64')
url="https://github.com/pvxe/efibootmgr-json"
license=('GPL2')
depends=('glibc' 'popt' 'jansson')
makedepends=('efivar' 'git')
provides=(efibootmgr)
conflicts=(efibootmgr)
source=(git+https://github.com/pvxe/efibootmgr-json)
sha512sums=('SKIP')
pkgver() {
cd efibootmgr-json
local commits=$(git rev-list --count HEAD)
local hash=$(git rev-parse --short HEAD)
printf 'r%s.g%s' "$commits" "$hash"
}
prepare() {
cd efibootmgr-json
# removing hotfix function declaration:
# https://github.com/rhboot/efibootmgr/issues/128
sed -e '/extern int efi_set_verbose/d' -i "src/efibootmgr.c"
}
build() {
cd efibootmgr-json
make libdir='/usr/lib' sbindir='/usr/bin' EFIDIR='arch' JSON=1
}
package() {
depends+=('libefiboot.so' 'libefivar.so')
cd efibootmgr-json
make DESTDIR="${pkgdir}" \
libdir='/usr/lib' \
sbindir='/usr/bin' \
EFIDIR='arch' \
install
install -vDm 644 {AUTHORS,README,README.md,TODO} \
-t "${pkgdir}/usr/share/doc/${pkgname}"
}
|