blob: 1809c919d1cd0134acd0eedaf5438b6f8d148d84 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer : Daniel Bermond <dbermond@archlinux.org>
# Contributor: Det
pkgname=egl-wayland-git
pkgver=1.1.9.r2.gdaab854
pkgrel=1
pkgdesc='EGLStream-based Wayland external platform (git version)'
arch=('x86_64')
url='https://github.com/NVIDIA/egl-wayland/'
license=('MIT')
depends=('wayland')
makedepends=('git' 'meson' 'eglexternalplatform' 'libglvnd>=1.3.4' 'wayland-protocols')
provides=('egl-wayland' 'libnvidia-egl-wayland.so')
conflicts=('egl-wayland')
source=('git+https://github.com/NVIDIA/egl-wayland.git'
'10_nvidia_wayland.json')
sha256sums=('SKIP'
'5cccf1905a266e8e34d5ad4aad4be85390e60b1a0850a29dd9d64adc641de412')
pkgver() {
git -C egl-wayland describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}
build() {
arch-meson build egl-wayland
ninja -C build
}
check() {
ninja -C build test
}
package() {
DESTDIR="$pkgdir" ninja install -C build
cp -dr --no-preserve='ownership' egl-wayland/include "${pkgdir}/usr"
install -D -m644 10_nvidia_wayland.json -t "${pkgdir}/usr/share/egl/egl_external_platform.d"
install -D -m644 egl-wayland/COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|