summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e24b4f606c5396940c7a9ac7c998e6999e892935 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Ner0 <darkelfdarkelf666@yahoo.co.uk>

pkgname=eidete-bzr
pkgver=r195
pkgrel=1
pkgdesc='Simple screencaster for the elementary project'
arch=('i686' 'x86_64')
url='https://launchpad.net/eidete'
license=('GPL3')
groups=('pantheon-unstable')
depends=('gst-plugins-base-libs' 'libwnck3'
         'libgranite.so')
makedepends=('bzr' 'cmake' 'granite-git' 'vala')
provides=('eidete')
conflicts=('eidete')
install='eidete.install'
source=('bzr+lp:eidete')
sha256sums=('SKIP')

pkgver() {
  cd eidete

  echo "r$(bzr revno)"
}

build() {
  cd eidete

  if [[ -d build ]]; then
    rm -rf build
  fi
  mkdir build && cd build

  cmake .. \
    -DCMAKE_BUILD_TYPE='Release' \
    -DCMAKE_INSTALL_PREFIX='/usr'
  make
}

package() {
  cd eidete/build

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: