summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7e577b48d6b06953152ac94b69b462841dcaba28 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>

pkgname=emacs-exwm-git
pkgver=r621.1821027
pkgrel=1
pkgdesc="Use emacs as windowmanager"
arch=('any')
url="https://github.com/emacs-exwm/exwm.git"
license=('GPL')
depends=('emacs-xelb-git')
makedepends=('git')
provides=('emacs-exwm')
conflicts=('emacs-exwm')
source=("git+https://github.com/emacs-exwm/exwm.git")
md5sums=('SKIP')
_gitname="exwm"

pkgver() {
  cd "$_gitname"
  printf "r%s.%s" $(git rev-list --count HEAD) $(git rev-parse --short HEAD)
}

build() {
  cd "$_gitname"
  emacs -Q -batch -L . -f batch-byte-compile *.el || true
}

package() {
  cd "$_gitname"
  for _i in *.el
  do
    install -Dm644 ${_i} "$pkgdir"/usr/share/emacs/site-lisp/exwm/${_i}
  done
  install -Dm644 README.md "$pkgdir"/usr/share/doc/exwm/README.md
  install -Dm644 xinitrc "$pkgdir"/usr/share/doc/exwm/sample-xinitrc
}