summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 335d3874db6956bf8c43cf42bd334ad3516c3dcd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Maintainer: sballert <sballert@posteo.de>

_gituser="victorhge"
_gitrepo="iedit"

pkgname=emacs-iedit-git
pkgver=r245.2ab2e8b
pkgrel=1
pkgdesc="Edit multiple regions simultaneously in a buffer or a region "
url="https://github.com/${_gituser}/${_gitrepo}"
arch=('any')
license=('GPL3')
depends=('emacs')
makedepends=('git')
provides=('emacs-iedit')
conflicts=('emacs-iedit')
source=("git+https://github.com/${_gituser}/${_gitrepo}.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_gitrepo"
  printf "r%s.%s" $(git rev-list --count HEAD) $(git rev-parse --short HEAD)
}

build() {
  cd "$_gitrepo"
  emacs -q --no-splash -batch -L . -f batch-byte-compile iedit{-lib,-rect,}*.el
}

package() {
  cd "$_gitrepo"
  install -d  "$pkgdir"/usr/share/emacs/site-lisp/${_gitrepo}/
  install -m644 iedit{-lib,-rect,}.el{c,} "$pkgdir"/usr/share/emacs/site-lisp/${_gitrepo}/
}