blob: 9f576ea3cff835c12b6f77d7cf9deff595a4080d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
|
# Maintainer: Jack Kamm <jackkamm AT gmail DOT com>
# Contributor: Jonathan Kotta <jpkotta AT gmail DOT com>
# Contributor: megadriver <megadriver at gmx dot com>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>
# Contributor: Renchi Raju <renchi@green.tam.uiuc.edu>
# Based on emacs from [extra] and emacs-bzr, emacs-git from the AUR
################################################################################
# Assign "YES" to the variable you want enabled; empty or any other value
# for NO.
# =================================================
#
################################################################################
JIT= # Enable native just-in-time compilation with libgccjit available
# in core.
#
# To compile all site-lisp on demand (repos/AUR packages,
# ELPA, MELPA, whatever), add
# (setq native-comp-deferred-compilation t)
# to your .emacs file.
#
# And to keep the eln cache clean add
# (setq native-compile-prune-cache t)
# to delete old versions.
################################################################################
################################################################################
pkgname=emacs-lucid
pkgver=29.3
_pkgver_major=${pkgver/.*}
pkgrel=1
pkgdesc="The extensible, customizable, self-documenting real-time display editor (Lucid toolkit version)"
arch=('x86_64')
url="http://www.gnu.org/software/emacs/emacs.html"
license=('GPL3')
depends=(
cairo
gmp
gnutls
hicolor-icon-theme
jansson
lcms2
libacl.so
libasound.so
libdbus-1.so
libfontconfig.so
libfreetype.so
libgdk_pixbuf-2.0.so
libgif.so
libgio-2.0.so
libglib-2.0.so
libgobject-2.0.so
libgpm.so
libharfbuzz.so
libice
libjpeg.so
libncursesw.so
libotf
libpng
librsvg-2.so
libsm
sqlite libsqlite3.so
libsystemd.so
libtiff.so
libtree-sitter.so
#libwebp.so
libwebpdemux.so
libx11
libxcb
libxcomposite
libxext
libxfixes
libxi
libxinerama
libxml2.so
libxmu
libxpm
libxrandr
libxrender
libxt
m17n-lib
xaw3d
xcb-util
zlib
)
optdepends=(
'lldb: For debugging with LLDB instead of GDB'
)
conflicts=(emacs)
provides=("emacs=$_pkgver_major")
validpgpkeys=('17E90D521672C04631B1183EE78DAE0F3115E06B' # Eli Zaretskii <eliz@gnu.org>
'CEA1DE21AB108493CC9C65742E82323B8F4353EE') # Stefan Kangas <stefankangas@gmail.com>
_source_url_prefix="ftp://ftp.gnu.org/gnu/emacs"
source=(${_source_url_prefix}/emacs-$pkgver.tar.xz
${_source_url_prefix}/emacs-$pkgver.tar.xz.sig)
b2sums=('73651c52e508d5341f66659bbaf98e839040239198cb66f62239f489a961794adf837d9a14e9b605f059b7b612803e0ce5998ec47100ba545db642baacdb55ec'
'SKIP')
################################################################################
################################################################################
if [[ $JIT == "YES" ]]; then
depends+=( 'libgccjit' );
fi
################################################################################
################################################################################
build() {
cd "$srcdir"/emacs-$pkgver
local _conf=(
--sysconfdir=/etc
--prefix=/usr
--libexecdir=/usr/lib
--with-tree-sitter
--localstatedir=/var
--disable-build-details
--with-modules
--with-x-toolkit=lucid
--without-gconf
--without-gsettings
--program-transform-name='s/^ctags$/ctags.emacs/'
)
################################################################################
if [[ $JIT == "YES" ]]; then
_conf+=( '--with-native-compilation=aot' );
fi
################################################################################
./configure "${_conf[@]}"
make
}
package() {
cd "$srcdir"/emacs-$pkgver
make DESTDIR="$pkgdir" install
# fix user/root permissions on usr/share files
find "$pkgdir"/usr/share/emacs/$pkgver -exec chown root:root {} \;
}
################################################################################
|