blob: f98e0595c96bfaf4eb9b06f7427fc892b687159d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: VinÃcius dos Santos Oliveira <vini.ipsmaker@gmail.com>
pkgname=emilua
pkgver=0.7.0
pkgrel=1
pkgdesc="Lua execution engine"
arch=('i686' 'x86_64')
url="https://gitlab.com/emilua/emilua"
license=('boost')
depends=('luajit' 'boost-libs' 'fmt' 'openssl' 'ncurses' 'serd' 'sord' 'liburing' 'libcap')
makedepends=('git' 'meson' 'boost' 'cereal' 're2c' 'gawk' 'gperf' 'asciidoctor')
source=("${pkgname}::git+https://gitlab.com/emilua/emilua.git#tag=v${pkgver}"
"trial-protocol::git+https://github.com/breese/trial.protocol.git#commit=79149f604a49b8dfec57857ca28aaf508069b669")
md5sums=('SKIP'
'SKIP')
#validpgpkeys=()
prepare() {
cd "${srcdir}/${pkgname}/subprojects"
ln -s "${srcdir}/trial-protocol" .
cp "packagefiles/trial.protocol/meson.build" "trial-protocol/"
}
build() {
arch-meson emilua build \
-D version_suffix=-arch${pkgrel} \
-D enable_file_io=true \
-D enable_io_uring=true
meson compile -C build
}
check() {
meson test --print-errorlogs -C build
}
package() {
meson install -C build --destdir "$pkgdir"
}
|