blob: 40a71d3682edfecf44f9f3b2ccc45b9655dd9294 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=ente-auth
pkgdesc="Open source 2FA authenticator, with end-to-end encrypted backups"
pkgver=4.3.2
pkgrel=1
arch=('x86_64' 'aarch64')
url="https://ente.io/auth"
license=('AGPL-3.0-or-later')
depends=(
'gtk3'
'libayatana-appindicator'
'libsecret'
'libsodium-1.0.18'
'sqlite'
)
makedepends=(
# 'chrpath'
'clang'
'cmake'
'git'
'ninja'
'unzip'
)
source=("git+https://github.com/ente-io/ente.git#tag=auth-v$pkgver"
'git+https://github.com/ente-io/sentry-dart.git'
'git+https://github.com/flutter/flutter.git'
'git+https://github.com/simple-icons/simple-icons.git'
'git+https://github.com/ente-io/PhotoSwipe.git'
'git+https://github.com/prateekmedia/flutter_distributor.git#branch=develop'
'enteauth.desktop')
sha256sums=('a1b9a1c02fb52e730b6c7f0a57fa26c81c05b98bf3bb66f473c3e99707cbe33b'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'c06f6e30813bd035245e1fb79a8c1b6c5284d98cd98a70e46b18c5a39e7b9aee')
prepare() {
cd ente
git submodule init
git config submodule.auth/thirdparty/sentry-dart.url "$srcdir/sentry-dart"
git config submodule.auth/flutter.url "$srcdir/flutter"
git config submodule.auth/assets/simple-icons.url "$srcdir/simple-icons"
git config submodule.web/apps/photos/thirdparty/photoswipe.url "$srcdir/PhotoSwipe"
git -c protocol.file.allow=always submodule update
cd auth
ln -sf "$srcdir/flutter_distributor" flutter/packages
export FLUTTER_HOME="$srcdir/ente/auth/flutter"
export PATH="${FLUTTER_HOME}/bin:${PATH}"
# Disable analytics
flutter --disable-analytics
# Ensure no build artifacts are cached
flutter clean
# Download dependencies
flutter pub get
}
build() {
cd ente/auth
export FLUTTER_HOME="$srcdir/ente/auth/flutter"
export HOME="${FLUTTER_HOME}"
export PATH="${FLUTTER_HOME}/bin:${PATH}"
export PATH="${PATH}":"${HOME}/.pub-cache/bin"
export LIBSODIUM_USE_PKGCONFIG=1
export PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:/usr/lib/sodium-1.0.18/pkgconfig/"
export LIBRARY_PATH="${LIBRARY_PATH}:/usr/lib/sodium-1.0.18/"
flutter config --no-analytics
dart --disable-analytics
dart pub global activate \
--source git https://github.com/prateekmedia/flutter_distributor \
--git-ref develop \
--git-path packages/flutter_distributor
flutter_distributor package --platform=linux --targets=zip --skip-clean
}
check() {
cd ente/auth
export FLUTTER_HOME="$srcdir/ente/auth/flutter"
export PATH="${FLUTTER_HOME}/bin:${PATH}"
flutter test
}
package() {
cd ente/auth
if [ "$CARCH" == "aarch64" ]; then
FLUTTER_ARCH=arm64
else
FLUTTER_ARCH=x64
fi
install -Dm755 build/linux/${FLUTTER_ARCH}/release/bundle/enteauth -t \
"$pkgdir/opt/$pkgname/"
cp -r build/linux/${FLUTTER_ARCH}/release/bundle/{data,lib} "$pkgdir/opt/$pkgname"
install -d "$pkgdir/usr/bin"
ln -s "/opt/$pkgname/enteauth" "$pkgdir/usr/bin/"
install -Dm644 assets/icons/auth-icon.png "$pkgdir/usr/share/pixmaps/enteauth.png"
install -Dm644 "$srcdir/enteauth.desktop" -t "$pkgdir/usr/share/applications/"
install -Dm644 linux/packaging/enteauth.appdata.xml -t "$pkgdir/usr/share/metainfo/"
# Remove insecure RUNPATH pointing to build dir
# chrpath --delete "$pkgdir/opt/$pkgname"/lib/*.so
}
|