PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: HurricanePootis <hurricanepootis@protonmail.com>
_pkgname=Epic-Asset-Manager
pkgname=epic-asset-manager
pkgver=3.8.6
pkgrel=1
pkgdesc="A frontend to Assets purchased on Epic Games Store"
arch=('x86_64')
url="https://github.com/AchetaGames/Epic-Asset-Manager"
license=('MIT')
depends=('glibc' 'gcc-libs' 'gtk4' 'gdk-pixbuf2' 'graphene' 'openssl' 'pango' 'bzip2' 'cairo' 'glib2' 'libadwaita' 'hicolor-icon-theme' 'dconf')
makedepends=('cargo' 'meson')
provides=(eam)
conflicts=(eam)
source=("$url/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('4c0ea9a9c7b4c82ac13514887dc608132816fb1eeb5b1e4c1619ea20412e2fc5')

prepare() {
	cd "$srcdir"
	[[ -d build ]] && rm -rf build
}

build() {
	cd "$srcdir"
	export RUSUTP_TOOLCAHIN=stable
	export CFLAGS="$CFLAGS -ffat-lto-objects"
	arch-meson \
	$_pkgname-$pkgver \
	build

	meson compile -C build
}

package() {
	cd "$srcdir"

	export RUSTUP_TOOLCHAIN=stable
	export CFLAGS="$CFLAGS -ffat-lto-objects"
	meson install -C build --destdir "$pkgdir"

	install -Dm644 "$srcdir/$_pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}