blob: ea2318903cdfafa00aaada6454b0679c8faccd56 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
# Contributor: Andre Klitzing <andre () incubo () de>
_model="201214w"
pkgname="epson-inkjet-printer-${_model}"
pkgver=1.0.1
pkgrel=1
pkgdesc="Epson inkjet printer driver (WF-M1030, WF-M1560, WF-M1561)"
arch=('x86_64')
url="https://download.ebz.epson.net/dsc/search/01/search/?OSC=LX"
license=('custom:Epson End User Software License Agreement')
depends=('epson-inkjet-printer-filter' 'gcc-libs' 'glibc')
_pkgsrc="${pkgname}-${pkgver}"
source=("https://download3.ebz.epson.net/dsc/f/03/00/15/69/61/da53ee2796d210d87d9970aab3aed67447e31098/${_pkgsrc}-1.src.rpm")
sha256sums=('5154aa57822d5a2638e571693a949225d4940ff4a1af98aa9baf62c910cdc6d0')
prepare() {
cd "${srcdir}"
bsdtar -xzf "${_pkgsrc}.tar.gz"
}
build() {
cd "${srcdir}/${_pkgsrc}/ppds"
find . -type f -name '*.ppd' -exec \
sed -i "s|/home/epson/projects/PrinterDriver/P2/_rpmbuild/SOURCES/${_pkgsrc}|/usr/share/epson-inkjet-printer-filter|g" "{}" +
}
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm644 "AUTHORS" "${pkgdir}/usr/share/doc/${pkgname}/AUTHORS"
install -vDm644 "Manual.txt" "${pkgdir}/usr/share/doc/${pkgname}/MANUAL"
install -vDm644 "README" "${pkgdir}/usr/share/doc/${pkgname}/README"
install -vDm644 "COPYING.EPSON" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
find "resource" -type f -exec \
install -vDm644 "{}" "${pkgdir}/usr/share/epson-inkjet-printer-filter/{}" \;
cd "${srcdir}/${_pkgsrc}/ppds"
find . -type f -exec \
install -vDm644 "{}" "${pkgdir}/usr/share/cups/model/${pkgname}/{}" \;
cd "${srcdir}/${_pkgsrc}/lib64"
find . -type f -exec \
install -vDm644 "{}" "${pkgdir}/usr/lib/{}" \;
cd "${pkgdir}/usr/lib"
for lib in *".so.${pkgver}"; do
base="${lib%.${pkgver}}"
ln -vsf "${lib}" "${base}"
ln -vsf "${lib}" "${base}.${pkgver%%.*}"
done
}
|