PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: AlphaJack <alphajack at tuta dot io>

pkgname="fava-investor-git"
pkgver=0.4.0.r0.g0e3f652
pkgrel=1
pkgdesc="Comprehensive set of reports, analyses, and tools for investments, for Beancount and Fava"
url="https://github.com/redstreet/fava_investor"
license=("GPL3")
arch=("any")
depends=(    "fava"
             "python-click-aliases"
             "python-importlib-metadata"
             "python-tabulate"
             "python-yfinance")
makedepends=("git"
             "python-build"
             "python-installer"
             "python-setuptools-scm"
             "python-wheel")
options=("!strip")
source=("git+$url")
sha256sums=("SKIP")

pkgver() {
 cd "fava_investor"
 git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build(){
 cd "fava_investor"
 python -m build --wheel --no-isolation
}

package(){
 cd "fava_investor"
 python -m installer --destdir="$pkgdir" dist/*.whl
}