PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Juanjo Gutierrez

# based on PKGBUILD for util-linux by:
# Maintainer: Tom Gundersen <teg@jklm.no>
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=fdformat
_pkgmajor=2.38
_realver=${_pkgmajor}.1
pkgver=${_realver/-/}
pkgrel=1
pkgdesc='fdformat from util-linux'
url='https://github.com/karelzak/util-linux'
arch=('x86_64')
makedepends=()
license=('GPL2')
validpgpkeys=('B0C64D14301CC6EFAEDF60E4E4B71D5EEC39C284')  # Karel Zak
source=("https://www.kernel.org/pub/linux/utils/util-linux/v${_pkgmajor}/util-linux-${_realver}.tar."{xz,sign})
sha256sums=('60492a19b44e6cf9a3ddff68325b333b8b52b6c59ce3ebd6a0ecaa4c5117e84f'
            'SKIP')

build() {
  cd "util-linux-${_realver}"

  ./configure \
    --prefix=/usr \
    --libdir=/usr/lib \
    --bindir=/usr/bin \
    --sbindir=/usr/bin \
    --localstatedir=/var \
    --disable-all-programs \
    --enable-fdformat

  make
}

package() {
  cd "util-linux-${_realver}"

  make DESTDIR="${pkgdir}" usrsbin_execdir=/usr/bin install

  ### locales are shipped as part of util-linux-libs
  rm -fr "${pkgdir}"/usr/share/locale

  ### common man pages already installed by util-linux
  rm -fr "${pkgdir}/usr/share/man/man1"
  rm -fr "${pkgdir}/usr/share/man/man3"
  rm -fr "${pkgdir}/usr/share/man/man5"
}