blob: e120146af6fadfe7b5a2fb66f59cbbe875e065b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Sébastien Luttringer
# Contributor: Marti Raudsepp <marti@juffo.org>
# Contributor: Manuel Mazzuola <origin.of@gmail.com>
# Contributor: Fabian Brosda <fabi3141@gmx.de>
pkgname=ferm
pkgver=2.7
pkgrel=1
pkgdesc='Tool to maintain complex firewalls'
arch=('any')
url='http://ferm.foo-projects.org/'
license=('GPL2')
depends=('iptables' 'perl')
optdepends=('ebtables' 'arptables' 'ipset')
backup=("etc/$pkgname.conf")
validpgpkeys=('0392335A78083894A4301C43236E8A58C6DB4512') # Max Kellermann <max@blarg.de>
source=(
"http://ferm.foo-projects.org/download/${pkgver:0:3}/$pkgname-$pkgver.tar.xz"{,.sig}
"$pkgname.service")
sha256sums=('c00d910d5394e69675608eb5ee0f504d5cfda41e990a2d9a91baac6df93e3f92'
'SKIP'
'b091bdef4b42c74d162de43b017c71bc00d7969b1a4f2d9188df01354c36a78e')
package() {
# software setup
cd $pkgname-$pkgver
make PREFIX="$pkgdir/usr" install
cd "$pkgdir"
# setup default config
install -D -m 644 usr/share/doc/ferm/examples/workstation.ferm etc/$pkgname.conf
# remove fancy docs
rm usr/share/doc/ferm/ferm.{html,txt}
# /usr merge
mv usr/sbin usr/bin
# systemd
install -Dm 644 "$srcdir/$pkgname.service" usr/lib/systemd/system/$pkgname.service
}
# vim:set ts=2 sw=2 et:
|