blob: 5891dc548851295776e7d27f924874e549bd74b9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Dct Mei <dctxmei@yandex.com>
# Maintainer: Eli Schwartz <eschwartz@archlinux.org>
# Contributor: Hyacinthe Cartiaux <hyacinthe.cartiaux@free.fr>
_pkgname=privacybadger
pkgname=firefox-esr-extension-${_pkgname}
pkgver=2024.2.6
pkgrel=1
pkgdesc="Block third party tracking in your browser"
arch=('any')
url="https://www.eff.org/privacybadger"
license=('GPL3')
#groups=('firefox-addons')
makedepends=("unzip")
source=("${_pkgname}-${pkgver}.xpi::https://www.eff.org/files/privacy-badger-eff-${pkgver}.xpi"
"${_pkgname}-${pkgver}.xpi.sig::https://www.eff.org/files/privacy-badger-eff-${pkgver}.xpi.sig")
noextract=("${_pkgname}-${pkgver}.xpi")
sha256sums=('d77f6f1fba99804d1c6869e608a7645dd2d8c71e0777b0d4ef3399ae8dcb28af'
'SKIP')
b2sums=('5d45dc74c4cd83f8cbe7760e0230343e3819c1220a7182d14adb5517852a3be6dceb79a441bdc7f979069ae38fffb48a8690c2c52d9266393207ca60fd74787d'
'SKIP')
validpgpkeys=('88F8662241B0C16C16E3B5A7950FC3999D80F309') # Alexei <alexei@eff.org>
prepare() {
cd "$srcdir"
unzip -qqo "${_pkgname}-${pkgver}.xpi" -d "${_pkgname}-${pkgver}"
}
package() {
depends=("firefox-esr")
cd "${srcdir}"
if [[ -f ${_pkgname}-${pkgver}/install.rdf ]]; then
_extension_id="$(sed -n '/.*<em:id>\(.*\)<\/em:id>.*/{s//\1/p;q}' ${_pkgname}-${pkgver}/install.rdf)"
else
_extension_id="$(sed -n 's/.*"id": "\(.*\)".*/\1/p' ${_pkgname}-${pkgver}/manifest.json)"
fi
_extension_dest="${pkgdir}/usr/lib/firefox-esr/browser/extensions/${_extension_id}"
# Should this extension be unpacked or not?
if grep -q '<em:unpack>true</em:unpack>' ${_pkgname}-${pkgver}/install.rdf 2>/dev/null; then
install -dm755 "${_extension_dest}"
cp -R ${_pkgname}-${pkgver}/* "${_extension_dest}"
chmod -R ugo+rX "${_extension_dest}"
else
install -Dm644 ${_pkgname}-${pkgver}.xpi "${_extension_dest}.xpi"
fi
}
|