blob: 1e4ebbf7f24069ba2ef7a43077bc69064990a8d9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Kamil Śliwak <cameel2@gmail.com>
_gecko_id="{59812185-ea92-4cca-8ab7-cfcacee81281}"
_name="10ten-ja-reader"
pkgname=firefox-extension-rikaichamp
pkgver=1.14.0
pkgrel=1
pkgdesc="Translate Japanese by hovering over words"
arch=('any')
url="https://github.com/birchill/${_name}"
license=('GPL3')
groups=("firefox-addons")
depends=("firefox")
makedepends=("yarn" "nodejs>=12")
source=("${_name}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('9a972de5b8ca449e060c0dabf9c8eddc0737b2b759612cda60c797e9e606b021')
build() {
cd "${_name}-${pkgver}"
export RELEASE_BUILD=1
yarn install --pure-lockfile
yarn package:firefox
}
check() {
cd "${_name}-${pkgver}"
yarn test:unit
}
package() {
cd "${_name}-${pkgver}"
install -D --mode 644 -- "dist-firefox-package/10ten_japanese_reader_rikaichamp_-${pkgver}.zip" "${pkgdir}/usr/lib/firefox/browser/extensions/${_gecko_id}.xpi"
}
|