PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Ewout van Mansom <ewout@vanmansom.name>
# Contributor: skrewball <aur at joickle dot com> gitlab.com/skrewball/aur
#
# # 
#  See INSTALL.md to setup firefox to use this theme when installed
#  in your system /usr/lib directory via pacman and this PKGBUILD.
# #

_pkgbase=firefox-gnome-theme
pkgname=firefox-gnome-theme-45
pkgver=119.r2.g3a02dce
pkgrel=1
pkgdesc='A GNOME theme for Firefox (GNOME 45 version)'
arch=('any')
url='https://github.com/rafaelmardojai/firefox-gnome-theme'
license=('Unlicense')
optdepends=('firefox: primary compatible browser'
            'librewolf: alternative compatible browser')
makedepends=('git')
provides=('firefox-gnome-theme')
conflicts=('firefox-gnome-theme' 'firefox-gnome-theme-git')
install="${_pkgbase}.install"
source=("${_pkgbase}::git+https://github.com/rafaelmardojai/firefox-gnome-theme.git#branch=gnome45"
        "INSTALL.md")
sha256sums=('SKIP'
            'f0fc2ccb43b813174e329fef74ab37a8cbfecd60168dbe05ccba999cfd8d222a')

pkgver() {
  cd "${_pkgbase}"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

package() {
  cd "${_pkgbase}"
  install -d "${pkgdir}/usr/lib/${_pkgbase}"
  cp -ra theme userChrome.css userContent.css configuration "${pkgdir}/usr/lib/${_pkgbase}"
  install -Dm644 README.md "${pkgdir}/usr/share/doc/${_pkgbase}/README.md"
  install -Dm644 ${srcdir}/INSTALL.md "${pkgdir}/usr/share/doc/${_pkgbase}/INSTALL.md"
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgbase}/LICENSE"
}