blob: 4c831176cb39d12e486daa87827f3d51644e360b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Maintainer: Evan Goode <mail@evangoo.de>
# Contributor: Giovanni Harting <anonfunc@archlinux.org>
# Contributor: Sefa Eyeoglu <contact@scrumplex.net>
# Contributor: txtsd <aur.archlinux@ihavea.quest>
# Contributor: seth <getchoo at tuta dot io>
# Contributor: fn2006 <usernamefn2006alreadyused@protonmail.com>
# Contributor: Lenny McLennington <lennymclennington@protonmail.com>
# Contributor: Elijah Gregg <lovetocode999@tilde.team>
# Contributor: Miko <mikoxyzzz@gmail.com>
# Contributor: Cheru Berhanu <aur attt cheru doot dev>
# Contributor: dada513 <dada513@protonmail.com>
pkgname=fjordlauncher
pkgver=11.1.1.0
pkgrel=1
pkgdesc="Prism Launcher fork with support for alternative auth servers"
arch=(x86_64)
url='https://github.com/unmojang/FjordLauncher'
license=('GPL-3.0-only AND LGPL-3.0-or-later AND LGPL-2.0-or-later AND Apache-2.0 AND MIT AND LicenseRef-Batch AND OFL-1.1')
depends=(
glibc
mesa-utils
libarchive
libgl
pciutils
qrencode
qt6-base
qt6-imageformats
qt6-networkauth
qt6-svg
zlib
hicolor-icon-theme
tomlplusplus
cmark
libstdc++
libgcc
)
makedepends=(
cmake
extra-cmake-modules
git
jdk17-openjdk
ninja
scdoc
gamemode
vulkan-headers
)
optdepends=(
'glfw: to use system GLFW libraries'
'openal: to use system OpenAL libraries'
'visualvm: Profiling support'
'xorg-xrandr: for older minecraft versions'
'orca: minecraft screen reader'
'flite: minecraft voice narration'
'java-runtime: use system java versions'
)
source=("https://github.com/unmojang/FjordLauncher/releases/download/$pkgver/FjordLauncher-$pkgver.tar.gz"
{lionshead,batch,mdi}.license)
b2sums=('d0e10b8b93cad52bd5ee5dd8ed853c3b9be5ab28f37517cd35db5415a2c5cb5df1d9a21e1e6bcb5743b175794b018474f4611913600f2e2990266e8e41ac387e'
'be4289832af95b1cd6e721dc16b84a034533de9718d9b43a49bd08dd6fe4e28eaa15228bfb311867b18fddbda1c9fc4c91f04c6d5c1a3bcc39aaa5161425e3ba'
'356248a6b86f06d260e0920b49d34034f79f9bc504c7fdc1849d929d2ff9b169e693a8269a2c0b34656b3802970d9b8be41a92b35177eaa3c4ccc89a702f5c9d'
'b35c447cd9223e096a2bb75e0741a7d0a3a1606af54c957e4f276f4e6861a9b3f06ae1d646137e8d2f24ba2238c9967c76eff8cc631a68d7e48e376056982cc6')
build() {
export PATH="/usr/lib/jvm/java-17-openjdk/bin/:$PATH"
local cmake_options=(
-B build
-S "FjordLauncher-$pkgver"
-G Ninja
-D Launcher_BUILD_PLATFORM=archlinux
-D Launcher_ENABLE_JAVA_DOWNLOADER=ON
-W no-dev
-D CMAKE_BUILD_TYPE=None
-D CMAKE_INSTALL_PREFIX=/usr
)
cmake "${cmake_options[@]}"
cmake --build build
}
check() {
ctest --test-dir build
}
package() {
# licenses
install -Dm644 lionshead.license -t "$pkgdir"/usr/share/licenses/$pkgname/
install -Dm644 batch.license -t "$pkgdir"/usr/share/licenses/$pkgname/
install -Dm644 mdi.license -t "$pkgdir"/usr/share/licenses/$pkgname/
DESTDIR="$pkgdir" cmake --install build
}
# vim:set ts=2 sw=2 et:
|