blob: ea8674d12672fe5329f86364db18efd893def0cd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
pkgname=flacon-git
pkgver=11.3.0.1.g4a5bc0b
pkgrel=1
pkgdesc="Extracts individual tracks from one big audio file containing the entire album of music and saves them as separate audio files. (Git Version)"
arch=('x86_64')
url='http://flacon.github.io'
license=('LGPL2.1')
depends=(
'gcc-libs' # libgcc_s.so libstdc++.so
'glibc' # libc.so libm.so
'qt5-base' # libQt5Core.so libQt5Gui.so libQt5Network.so libQt5Widgets.so
'uchardet' # libuchardet.so
'taglib' # libtag.so
'hicolor-icon-theme'
)
makedepends=(
'git'
'cmake'
'qt5-tools'
)
optdepends=(
'faac: For AAC support'
'flac: For FLAC support'
'lame: For MP3 support'
'mac: For APE support'
'mp3gain: For MP3 Replay Gain support'
'vorbis-tools: For OGG support'
'opus-tools: For OPUS support'
'ttaenc: For TrueAudio support'
'vorbisgain: For OGG Replay Gain support'
'wavpack: For WavPack support'
'alacenc-git: For ALAC Support'
'sox: for SOX support'
)
checkdepends=(
'yaml-cpp'
'faac'
'flac'
'lame'
'mac'
'vorbis-tools'
'opus-tools'
'ttaenc'
'wavpack'
'alacenc-git'
'sox'
)
conflicts=('flacon')
provides=('flacon')
source=('git+https://github.com/flacon/flacon.git')
sha256sums=('SKIP')
options=('debug')
pkgver() {
cd flacon
echo "$(git describe --long --tags | tr - . | tr -d v)"
}
build() {
cmake -S flacon -B build \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr \
-DBUILD_TESTS=Yes
cmake --build build
}
check() {
cd build
ctest --output-on-failure
}
package() {
DESTDIR="${pkgdir}" cmake --install build
}
|