blob: e380d35f337290af9d93cb46617c697fd1521482 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
_binname="flow"
_pkgname="${_binname}-cli"
pkgname="${_pkgname}-bin"
pkgver=2.2.0
pkgrel=1
pkgdesc="A command-line interface that provides useful utilities for building Flow applications"
arch=('x86_64' 'aarch64')
url="https://docs.onflow.org/flow-cli"
_url="https://github.com/onflow/${_pkgname}"
license=('Apache-2.0')
depends=('glibc')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
_pkgsrc="${_pkgname}-${pkgver}"
source_x86_64=("${_pkgsrc}-x86_64.tar.gz::${_url}/releases/download/v${pkgver}/${_pkgname}-v${pkgver}-linux-amd64.tar.gz")
source_aarch64=("${_pkgsrc}-aarch64.tar.gz::${_url}/releases/download/v${pkgver}/${_pkgname}-v${pkgver}-linux-arm64.tar.gz")
b2sums_x86_64=('3530866c822c33cb6b3d2e9c28d460bc1649cac3a73d1327d94ffbb20db31943e5392537d6f501476c442ba1b932d92e46e2ebaacdeacb0e31e79ad4830b9bfa')
b2sums_aarch64=('81872f095d68fc547a72112a782215c73327f84118f03d75d365bcefc58bd74d5dcb6aaa0f0778a44f9f90cbacf527c24664161248fb2156fb9e16c6b43cf7fc')
prepare() {
cd "${srcdir}"
mkdir -p "completions"
mv -f "${_pkgname}" "${_binname}"
}
build() {
cd "${srcdir}"
for _sh in bash fish zsh powershell; do
./"${_binname}" completion "${_sh}" > "completions/${_binname}.${_sh}"
done
}
package() {
cd "${srcdir}"
install -vDm755 "${_binname}" "${pkgdir}/usr/bin/${_binname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
cd "completions"
install -vDm644 "${_binname}.bash" "${pkgdir}/usr/share/bash-completion/completions/${_binname}"
install -vDm644 "${_binname}.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${_binname}.fish"
install -vDm644 "${_binname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${_binname}"
install -vDm644 "${_binname}.powershell" "${pkgdir}/usr/share/powershell/Modules/${_binname}/${_binname}.ps1"
}
|