PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: Mark Wagie <mark dot wagie & proton dot me>
# Contributor: Igor Dyatlov <dyatlov.igor@protonmail.com>
pkgname=flowtime
pkgver=6.5
pkgrel=1
pkgdesc="Get what motivates you done, without losing concentration"
arch=('x86_64' 'aarch64')
url="https://github.com/Diego-Ivan/Flowtime"
license=('GPL-3.0-or-later')
depends=('libadwaita' 'libgee' 'libportal-gtk4' 'libxml2')
makedepends=('blueprint-compiler' 'git' 'meson' 'vala')
checkdepends=('appstream-glib')
_commit=e6bc082a30e2e135086ad91435451b7da3751465  # tags/6.5^0
source=("git+https://github.com/Diego-Ivan/Flowtime.git#commit=${_commit}")
sha256sums=('c00589598d5ede19365f1d3eb4107df230b4b43951ce4c5d42e19b6ba734d0c0')

pkgver() {
  cd Flowtime
  git describe --tags | sed 's/^v//;s/-/+/g'
}

build() {
  arch-meson Flowtime build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs || :
}

package() {
  meson install -C build --destdir "$pkgdir"
}