blob: a884c644729eeff12ca0f3636b78c8561ade76e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: LaraCraft304 <lara@craft.net.br>
# Contributor: SpepS <dreamspepser at yahoo dot it>
pkgname=fltk11
pkgver=1.1.10
pkgrel=3
pkgdesc="Graphical user interface toolkit for X. Legacy 1.1.xx version."
arch=(i686 x86_64)
url="http://www.fltk.org/"
license=('GPL')
depends=('bash' 'zlib' 'libjpeg' 'libxft' 'libxext')
makedepends=('mesa')
provides=("${pkgname%11}=$pkgver")
source=("http://fltk.org/pub/fltk/$pkgver/fltk-$pkgver-source.tar.bz2")
md5sums=('a1765594bc427ff892e36089fe1fa672')
build() {
cd "$srcdir/${pkgname%11}-$pkgver"
LDFLAGS="${LDFLAGS//,--as-needed}" LIBS="-lfontconfig" \
./configure --prefix=/usr \
--libdir=/usr/lib/${pkgname%11}-${pkgver%.10} \
--includedir=/usr/include/${pkgname%11}-${pkgver%.10} \
--enable-threads \
--enable-xft \
--enable-shared \
--enable-xdbe \
--enable-localpng
make
}
package() {
cd "$srcdir/${pkgname%11}-$pkgver"
make DESTDIR="$pkgdir" install
# remove unneeded stuff
rm -rf "$pkgdir/usr/share"
# rename apps
cd "$pkgdir/usr/bin"
mv ${pkgname%11}-config ${pkgname%11}-${pkgver%.10}-config
mv fluid fluid-${pkgver%.10}
# static libs permission fix
chmod 644 "$pkgdir/usr/lib/${pkgname%11}-${pkgver%.10}/"*.a
}
|