blob: e958d034d302e6d31c1277f48435b905394bb434 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Arvid Norlander <VorpalBlade (at) users DOT noreply DOT github DOT com>
pkgname=fluxengine-git
pkgver=r3289.909fac72
pkgrel=1
pkgdesc="PSOC5 floppy disk imaging interface"
arch=('x86_64')
url="http://cowlark.com/fluxengine/"
license=('MIT')
depends=(
'curl'
'dbus'
'file'
'fmt'
'freetype2'
'glfw'
'libfmt.so'
'libprotobuf.so'
'libudev.so'
'mbedtls'
'md4c'
'protobuf'
'sqlite3'
'wxwidgets-gtk3'
'xz'
'zlib'
)
makedepends=(
'boost'
'clang'
'cli11'
'git'
'ninja' # TODO: Doesn't seem to be used any more?
'nlohmann-json'
'python-pyhamcrest'
'python'
'xxd'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/davidgiven/fluxengine.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/${pkgname%-git}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/${pkgname%-git}"
# Make all depends on tests, but we want to run them in check() instead.
make binaries
}
check() {
cd "$srcdir/${pkgname%-git}"
make tests
}
package() {
cd "$srcdir/${pkgname%-git}"
for e in fluxengine fluxengine-gui brother120tool brother240tool upgrade-flux-file; do
install -D "$e" "$pkgdir/usr/bin/$e"
done
install -Dm 644 COPYING.md "$pkgdir/usr/share/licenses/$pkgname/COPYING.md"
# Installing docs is not yet supported in a reasonable way by upstream.
}
|