PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Mihai Bişog <mihai.bisog at [gmail] d0t com>
pkgname=fmt
pkgver=5.2.0
pkgrel=1
pkgdesc="Open-source formatting library for C++."
arch=("i686" "x86_64")
url="http://fmtlib.net"
license=("BSD")
makedepends=("cmake")

source=("https://github.com/fmtlib/fmt/archive/$pkgver.tar.gz")
md5sums=('4b11dd96dfc0b501c66d0f6d3da693a8')

build() {
    cd "$pkgname-$pkgver"
    mkdir -p build && cd build

    cmake -DCMAKE_BUILD_TYPE=Release      \
          -DCMAKE_INSTALL_PREFIX=/usr     \
          -DCMAKE_INSTALL_LIBDIR=/usr/lib \
          -DFMT_DOC=OFF                   \
          ..
    make
}

check() {
    cd "$pkgname-$pkgver/build"
    make test
}

package() {
    cd "$pkgname-$pkgver/build"
    make DESTDIR="$pkgdir" install
    install -D -m644 ../LICENSE.rst "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    install -D -m644 ../ChangeLog.rst "${pkgdir}/usr/share/doc/${pkgname}/ChangeLog.rst"
}