PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer:
# Contributor: Tomoghno Sen <tomoghno@outlook.com>

_pkgname="fondo"
pkgname="$_pkgname"
pkgver=1.6.1
pkgrel=4
pkgdesc='Wallpaper App for Linux'
url="https://github.com/calo001/fondo"
license=('AGPL-3.0-or-later')
arch=('x86_64')

depends=(
  'elementary-icon-theme'
  'granite'
  'gtk-theme-elementary'
  'json-glib'
  'libhandy'
  'libsoup'

  ## implicit
  #dconf
  #glib2
  #gtk3
  #hicolor-icon-theme
  #libgee
)
makedepends=(
  'git'
  'meson'
  'vala'
)

source=(
  "$_pkgname"::"git+$url.git#tag=$pkgver"
  "elementary-theme.patch"
)
sha256sums=(
  'SKIP'
  'e2204425522f276d7604f7a3b6471d85cc8d11ede2b2d6b12d66a254f581ec9b'
)

prepare() {
  cd "$_pkgname"
  patch -p1 -i "../elementary-theme.patch"
}

build() {
  arch-meson "$_pkgname" build
  meson compile -C build
}

package() {
  meson install -C build --destdir "$pkgdir"
}