PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: Luke Taylor <luket1@proton.me>

pkgname=fooyin-git
pkgver=0.3.10
pkgrel=1
pkgdesc="A customisable music player"
url="https://github.com/ludouzi/fooyin"
arch=('any')
license=('GPL-3.0-only')
depends=(
    'qt6-base'
    'qt6-svg'
    'alsa-lib'
    'taglib'
    'ffmpeg'
    'qcoro-qt6'
    'kdsingleapplication'
    'hicolor-icon-theme'
    'glibc'
    'gcc-libs'
)
makedepends=(
    'cmake'
    'git'
    'ninja'
    'pkgconf'
    'qt6-tools'
)
optdepends=(
    'sdl2:     For the SDL2 audio output plugin'
    'libpipewire: For the PipeWire audio output plugin'
)
provides=('fooyin')
conflicts=('fooyin')
source=("$pkgname"::"git+https://github.com/ludouzi/fooyin.git")
sha256sums=('SKIP')

pkgver() {
  cd "${srcdir}/$pkgname"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "${srcdir}/$pkgname"
  cmake -S . -B build -G Ninja \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_PCH=ON
  cmake --build build
}

package() {
  cd "${srcdir}/$pkgname"
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 "${srcdir}/$pkgname/COPYING" "${pkgdir}/usr/share/licenses/fooyin/LICENSE"
}