summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: a844978964512d6aaf9994761ab252ec29a1fdbc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: Frederic Bezies <fredbezies at gmail dot com>
# Contributor: Philip Goto <philip.goto@gmail.com>

pkgname=fragments-git
pkgver=1.9.1.r54.gae38fee
pkgrel=2
pkgdesc="BitTorrent client for GNOME"
arch=(i686 x86_64 armv6h armv7h)
url="https://gitlab.gnome.org/World/Fragments"
license=(GPL3)
depends=(gtk4 libadwaita transmission-cli)
makedepends=(git meson rust)
provides=(fragments)
conflicts=(fragments)
source=("git+https://gitlab.gnome.org/World/Fragments.git")
sha256sums=('SKIP')

pkgver() {
    cd Fragments
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    arch-meson Fragments build
    ninja -C build
}

check() {
    ninja -C build test
}

package() {
    DESTDIR="$pkgdir/" ninja -C build install
}