PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: italoghost <eduprodive at posteo dot me>

pkgname=freetube-electron-git
_pkgname=FreeTube
pkgver=0.23.3.beta.r8309.bca1cbf
pkgrel=1
pkgdesc='A private YouTube client - built from latest git, with the default electron.'
arch=('x86_64')
url="https://freetubeapp.io"
license=('AGPL-3.0-or-later')
makedepends=('git' 'yarn')
provides=("${pkgname%-electron-git}")
conflicts=("${pkgname%-electron-git}")
source=(git+https://github.com/FreeTubeApp/FreeTube
       freetube.desktop)
sha256sums=("SKIP" 
            "496fc67b30fa66e8eff1e551121e5bb7ae0253bfb804b3a902d4e7bd3cdcbc26")

pkgver() {
  cd "$srcdir/$_pkgname"
  printf "%s.r%s.%s" "$(git tag --sort=committerdate | tail -1 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g')" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

prepare() {
  sed -i "s/targets = Platform.LINUX.*/targets = Platform.LINUX.createTarget(['dir'], arch)/" "$srcdir/$_pkgname/_scripts/build.js"
}

build() {
  cd $_pkgname
  yarn install
  yarn run build
}

package() {
  install -d "${pkgdir}/usr/lib/freetube"
  install -d "${pkgdir}/usr/bin"

  # copying libs
  cp -R ./$_pkgname/build/linux-unpacked/. "${pkgdir}/usr/lib/freetube/"

  # executable
  ln -s /usr/lib/freetube/freetube "${pkgdir}/usr/bin/freetube"
  
  # licence
  install -Dm644 ./$_pkgname/LICENSE "${pkgdir}/usr/share/licenses/freetube/LICENSE"

  # icon
  install -Dm644 ./$_pkgname/_icons/icon.svg "${pkgdir}/usr/share/pixmaps/freetube.svg"
  
  # desktop file
  install -Dm644 ./freetube.desktop "${pkgdir}/usr/share/applications/freetube.desktop"
}