blob: 88f173157363f6d877985f104aceeca092d17523 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer: Charles Bos <charlesbos1 AT gmail>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=freetype2-ttmetrics
pkgver=2.8
pkgrel=2
pkgdesc="Font rasterization library with TrueType metrics enabled"
arch=(i686 x86_64)
license=('GPL')
url="https://www.freetype.org/"
# adding harfbuzz for improved OpenType features auto-hinting
# introduces a cycle dep to harfbuzz depending on freetype wanted by upstream
depends=('zlib' 'bzip2' 'sh' 'libpng' 'harfbuzz')
makedepends=('libx11')
provides=("libfreetype.so" "freetype2=$pkgver")
conflicts=('freetype2')
install=freetype2.install
backup=('etc/profile.d/freetype2.sh')
source=(https://download-mirror.savannah.gnu.org/releases/freetype/freetype-${pkgver}.tar.bz2
https://download-mirror.savannah.gnu.org/releases/freetype/freetype-doc-${pkgver}.tar.bz2
0001-Enable-table-validation-modules.patch
0002-Enable-subpixel-rendering.patch
0003-Enable-infinality-subpixel-hinting.patch
0004-Enable-long-PCF-family-names.patch
freetype2.sh
enable_truetype_like_size_metrics.patch
revert_allow_linear_scaling.patch)
sha1sums=('42c6b1f733fe13a3eba135f5025b22cb68450f91'
'5b221ee14fe674cd5f6db0193d55360bc0bd3655'
'c3e91e668936206d3c158bffde0f69788a086a5b'
'4ff958229a7f87e04a9894d5a6ed2df227071931'
'81586014ea44375ddc85dd9dbcabae6e91c34d62'
'334f229875039794adeb574e27d365bb445fb314'
'bc6df1661c4c33e20f5ce30c2da8ad3c2083665f'
'833a8622bc61fc6f41c0e87c3614dec73490c9b1'
'f2cc372aedce56b387ee0c5403745d642bd44fe8')
prepare() {
# Rename source dir to allow building the demos
mv freetype-${pkgver} freetype2
cd freetype2
patch -Np1 -i ../0001-Enable-table-validation-modules.patch
patch -Np1 -i ../0002-Enable-subpixel-rendering.patch
patch -Np1 -i ../0003-Enable-infinality-subpixel-hinting.patch
patch -Np1 -i ../0004-Enable-long-PCF-family-names.patch
# See https://bbs.archlinux.org/viewtopic.php?id=226380
patch -Np1 -i ../enable_truetype_like_size_metrics.patch
# Also see https://bbs.archlinux.org/viewtopic.php?id=226380
patch -Np1 -i ../revert_allow_linear_scaling.patch
}
build() {
cd freetype2
./configure --prefix=/usr --disable-static
make
}
check() {
cd freetype2
make -k check
}
package() {
cd freetype2
make DESTDIR="${pkgdir}" install
install -Dm644 ../freetype2.sh "${pkgdir}/etc/profile.d/freetype2.sh"
# Package docs
install -d "${pkgdir}/usr/share/doc"
cp -a docs "${pkgdir}/usr/share/doc/freetype2"
}
|