PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: Ivy Foster <code@iff.ink>

pkgbase=frotz-git
pkgname=(frotz-dumb-git frotz-ncurses-git frotz-sdl-git)
pkgver=2.54.r130.g07a7d5f
pkgrel=1
pkgdesc='Z-machine interpreter for interactive fiction games'
makedepends=('git' 'libao' 'libmodplug' 'libsamplerate' 'libsndfile' 'libvorbis' 'ncurses'
     	'freetype2' 'libjpeg-turbo' 'libpng' 'sdl2' 'sdl2_mixer' 'zlib')

arch=(x86_64)
url='https://gitlab.com/DavidGriffith/frotz'
license=(GPL)
source=('git+https://gitlab.com/DavidGriffith/frotz.git')
md5sums=(SKIP)

pkgver() {
	cd frotz
	git describe | sed 's@-\(.*\)-@.r\1.@'
}

build() {
	cd frotz
	make PREFIX=/usr dumb ncurses sdl
}

package_frotz-dumb-git() {
	pkgdesc='Z-machine interpreter for interactive fiction games, for dumb terminals or scripting'
	depends=('glibc')
	provides=('dfrotz' 'frotz-dumb')
	conflicts=('frotz-dumb')

	cd frotz
	make DESTDIR="$pkgdir" PREFIX=/usr install_dumb
}

package_frotz-ncurses-git() {
	pkgdesc='ncurses-based Z-machine interpreter for interactive fiction games'
	provides=('frotz' 'frotz-ncurses')
	conflicts=('frotz-ncurses')
	depends=('libao' 'libmodplug' 'libsamplerate' 'libsndfile' 'ncurses')

	cd frotz
	make DESTDIR="$pkgdir" PREFIX=/usr install_frotz
}

package_frotz-sdl-git() {
	pkgdesc='Graphical Z-machine interpreter for interactive fiction games'
	provides=('sfrotz' 'frotz-sdl')
	conflicts=('frotz-sdl')
	depends=('freetype2' 'libjpeg-turbo' 'sdl2_mixer')

	cd frotz
	make DESTDIR="$pkgdir" PREFIX=/usr install_sdl
}