blob: 1a304dc9f1c9b10728b5cfa7aa2d33554e1a5422 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Maintainer: Juergen Werner <juergen at opensourcerouting dot org>
# Contributor: Shalygin Konstantin <k0ste at k0ste dot ru>
pkgname='frr-git'
pkgver=7.6.dev.r22256
pkgrel=1
pkgdesc='FRRouting (quagga fork) supports BGP4, OSPFv2, OSPFv3, ISIS, RIP, RIPng, PIM, LDP, NHRP and EIGRP.'
arch=('x86_64')
url="https://frrouting.org/"
license=('GPL2')
depends=('pam' 'json-c' 'net-snmp' 'rtrlib' 'libyang>=1.0.184' 'libunwind' 'python' 'c-ares')
makedepends=('net-snmp' 'bison' 'c-ares' 'perl-xml-libxml' 'python-sphinx' 'git')
optdepends=('rsyslog: syslog support')
conflicts=('quagga' 'babeld' 'quagga_cumulus' 'frr')
provides=('quagga' 'quagga_cumulus' 'frr')
backup=("etc/frr/frr.conf"
"etc/frr/daemons"
"etc/frr/vtysh.conf")
source=("git+https://github.com/FRRouting/frr.git"
"frr.sysusers"
"frr.tmpfiles")
sha256sums=('SKIP'
'e656acefc2c318a94c2d3011ecef2bed75d70852f1e642a3a1d331d860c8735b'
'4405c151caa45c02f000d7f03a998c56123c02c13d21af33e98314a73ef99e6a')
pkgver() {
cd frr
source config.version
echo "${DIST_PACKAGE_VERSION}.r$(git rev-list --count HEAD)" | sed 's/-/./g'
}
prepare() {
cd "${srcdir}/frr"
autoreconf -fvi
./configure \
--prefix="/usr" \
--sbindir="/usr/bin" \
--sysconfdir="/etc/frr" \
--localstatedir="/run/frr" \
--enable-exampledir="/usr/share/doc/frr/examples" \
--with-libpam \
--enable-snmp="agentx" \
--enable-multipath=256 \
--enable-user="frr" \
--enable-group="frr" \
--enable-vty-group="frrvty" \
--enable-configfile-mask="0640" \
--enable-logfile-mask="0640" \
--enable-shell-access \
--enable-systemd \
--enable-rpki \
--enable-fpm
}
build() {
cd "${srcdir}/frr"
make
}
package() {
cd "${srcdir}/frr"
make DESTDIR="${pkgdir}" install
pushd "redhat"
install -Dm0644 "frr.logrotate" "${pkgdir}/etc/logrotate.d/frr"
install -Dm0644 "frr.pam" "${pkgdir}/etc/pam.d/frr"
popd
install -Dm0644 "${srcdir}/frr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/frr.conf"
install -Dm0644 "${srcdir}/frr.sysusers" "${pkgdir}/usr/lib/sysusers.d/frr.conf"
pushd "tools"
sed -ri 's|/usr/lib/frr/|/usr/bin/|g' "frr.service"
install -Dm0644 "frr.service" "${pkgdir}/usr/lib/systemd/system/frr.service"
popd
pushd "tools/etc"
install -Dm0640 "frr/daemons" "${pkgdir}/etc/frr/daemons"
install -Dm0640 "frr/frr.conf" "${pkgdir}/etc/frr/frr.conf"
install -Dm0640 "frr/vtysh.conf" "${pkgdir}/etc/frr/vtysh.conf"
install -Dm0644 "iproute2/rt_protos.d/frr.conf" "${pkgdir}/etc/iproute2/rt_protos.d/frr.conf"
install -Dm0644 "rsyslog.d/45-frr.conf" "${pkgdir}/etc/rsyslog.d/45-frr.conf"
popd
}
|