blob: 1b60a6c86a6fb8858a3e23c2df5466a35da084c7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
#Maintainer: Simon Eriksson <simon.eriksson.1187+aur AT gmail.com>
pkgname=g64drive
pkgver=0.3.2
pkgrel=1
pkgdesc='Portable Linux/Mac tool for Retroactive 64drive'
arch=('x86_64')
license=('MIT')
url='https://github.com/rasky/g64drive'
makedepends=('go')
depends=('libftdi')
source=("https://github.com/rasky/g64drive/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('5a3333587f090e7b5cbccbe8efccf3fb585aeefe5692e80a76269fc718495534')
prepare() {
cd g64drive-${pkgver}
mkdir -p build/
}
build() {
cd g64drive-${pkgver}
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o build
}
package() {
cd g64drive-${pkgver}
install -Dm755 build/g64drive "$pkgdir"/usr/bin/g64drive
#install license
install -Dm644 LICENSE.mit "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
}
|