blob: 517fdadc3f4f4b26b7a369a63f64c51357392eda (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: katt <magunasu.b97@gmail.com>
# Contributor: LLL2yu <lll2yu@protonmail.com>
pkgname=gallery-dl
pkgver=1.32.2
pkgrel=1
pkgdesc='Command-line program to download image-galleries and collections from several image hosting sites'
arch=(any)
url=https://codeberg.org/mikf/gallery-dl
license=(GPL-2.0-or-later)
depends=(python python-requests)
makedepends=(python-build python-installer python-setuptools python-wheel git)
checkdepends=(yt-dlp)
optdepends=(
'yt-dlp: HLS/DASH video downloads, ytdl integration'
'youtube-dl: HLS/DASH video downloads, ytdl integration'
'ffmpeg: Pixiv Ugoira conversion'
'mkvtoolnix-cli: Accurate Ugoira frame timecodes'
'python-pysocks: SOCKS proxy support'
'python-brotli: Brotli compression support'
'python-brotlicffi: Brotli compression support'
'python-zstandard: Zstandard compression support'
'python-yaml: YAML configuration file support'
'python-toml: TOML configuration file support for Python<3.11'
'python-secretstorage: GNOME keyring passwords for --cookies-from-browser'
'python-psycopg: PostgreSQL support'
'python-truststore: Support using system certificates'
'python-jinja: Jinja template support'
)
source=(git+"${url}".git#tag=v"${pkgver}"?signed)
validpgpkeys=(3E09F5908333DD83DBDCE7375680CA389D365A88) #Mike Fährmann
sha512sums=('8b985d2d0ec7d58123515140e009992d04d81cde47f6d79d36674e9add77cff0fcba74555cd9bf85c58cc420f3701a5eb7e465536f08006cd13a636f0de85298')
prepare() {
# Clean out old wheels etc.
git -C "${pkgname}" clean -dfx
}
build() {
cd ${pkgname}
make
python -m build --wheel --no-isolation
}
check() {
make -C ${pkgname} test
}
package() {
cd ${pkgname}
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}" docs/{configuration.rst,formatting.md,gallery-dl-example.conf} CHANGELOG.md
}
|