blob: 4794eee257a94dbf705187e196186fa2d36215c0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
|
# Maintainer: Taijian <taijian@posteo.de>
# Contributor: Sebastian Lau <lauseb644 _at_ gmail _dot_ com>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Damian01w <damian01w@gmail.com>
_pkgbase=gdm
pkgbase=gdm-nox
pkgname=(gdm-nox libgdm-nox)
pkgver=46.0
pkgrel=1
pkgdesc="Display manager and login screen, but without the dependency on xorg-server"
url="https://wiki.gnome.org/Projects/GDM"
arch=(x86_64)
license=('GPL-2.0-or-later')
depends=(
accountsservice
audit
bash
gcc-libs
gdk-pixbuf2
glib2
glibc
gnome-session
gnome-shell
gtk3
json-glib
keyutils
libcanberra
libgudev
libx11
libxau
libxcb
libxdmcp
pam
systemd
systemd-libs
upower
)
makedepends=(
dconf
plymouth
python-packaging
yelp-tools
gobject-introspection
git
docbook-xsl
meson
)
checkdepends=(check)
_commit=a5b591cd8d1db5c5d1ebe67d10ec3fe57b9bbded # tags/46.0^0
source=("git+https://gitlab.gnome.org/GNOME/gdm.git#commit=$_commit"
0001-Xsession-Don-t-start-ssh-agent-by-default.patch
)
sha256sums=('bf1a7723223164be9afaa7f15af0da3251112a527b74f2fca7ef192ff2ffba9c'
'39a7e1189d423dd428ace9baac77ba0442c6706a861d3c3db9eb3a6643e223f8')
pkgver() {
cd $_pkgbase
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
prepare() {
cd $_pkgbase
# Don't start ssh-agent by default
git apply -3 ../0001-Xsession-Don-t-start-ssh-agent-by-default.patch
}
build() {
local meson_options=(
-D dbus-sys="/usr/share/dbus-1/system.d"
-D default-pam-config=arch
-D default-path="/usr/local/bin:/usr/local/sbin:/usr/bin"
-D ipv6=true
-D run-dir=/run/gdm
-D selinux=disabled
)
arch-meson gdm build "${meson_options[@]}"
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
_pick() {
local p="$1" f d; shift
for f; do
d="$srcdir/$p/${f#$pkgdir/}"
mkdir -p "$(dirname "$d")"
mv "$f" "$d"
rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
done
}
package_gdm-nox() {
depends+=(libgdm-nox)
optdepends=('fprintd: fingerprint authentication')
provides=("gdm")
conflicts=("gdm")
replaces=("gdm-plymouth-nox")
backup=(
etc/gdm/PostSession/Default
etc/gdm/PreSession/Default
etc/gdm/Xsession
etc/gdm/custom.conf
etc/pam.d/gdm-autologin
etc/pam.d/gdm-fingerprint
etc/pam.d/gdm-launch-environment
etc/pam.d/gdm-password
etc/pam.d/gdm-smartcard
)
groups=(gnome)
install=gdm.install
meson install -C build --destdir "$pkgdir"
cd "$pkgdir"
install -d -o 0 -g 0 -m 0755 var
install -d -o 0 -g 0 -m 0755 var/lib
install -d -o 120 -g 120 -m 1770 var/lib/gdm
install -d -o 120 -g 120 -m 0700 var/lib/gdm/.config
install -d -o 120 -g 120 -m 0700 var/lib/gdm/.config/pulse
install -d -o 120 -g 120 -m 0700 var/lib/gdm/.local
install -d -o 120 -g 120 -m 0755 var/lib/gdm/.local/share
install -d -o 120 -g 120 -m 0755 var/lib/gdm/.local/share/applications
# https://src.fedoraproject.org/rpms/gdm/blob/master/f/default.pa-for-gdm
install -o120 -g120 -m644 /dev/stdin var/lib/gdm/.config/pulse/default.pa <<END
load-module module-device-restore
load-module module-card-restore
load-module module-udev-detect
load-module module-native-protocol-unix
load-module module-default-device-restore
load-module module-always-sink
load-module module-intended-roles
load-module module-suspend-on-idle
load-module module-systemd-login
load-module module-position-event-sounds
END
install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/gdm.conf" <<END
g gdm 120 -
u gdm 120 "Gnome Display Manager" /var/lib/gdm
END
_pick libgdm usr/include
_pick libgdm usr/lib/{girepository-1.0,libgdm*,pkgconfig}
_pick libgdm usr/share/{gir-1.0,glib-2.0}
}
package_libgdm-nox() {
pkgdesc+=" - support library"
depends=(
dconf
gcc-libs
glib2
glibc
libg{lib,object,io}-2.0.so
libsystemd.so
systemd-libs
)
provides=(libgdm)
conflicts=(libgdm)
replaces=("libgdm-plymouth-nox")
mv libgdm/* "$pkgdir"
}
|