PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107

# Maintainer:
# Contributor: Mitch Bigelow <mitch.bigelow at gmail.com>
# Contributer: Steven Honeyman <stevenhoneyman at gmail com>

## options
: ${_use_sodeps:=false}

_pkgname="geeqie"
pkgname="$_pkgname-git"
pkgver=3.2.r14.g1820953
pkgrel=1
pkgdesc='Lightweight image viewer'
url="https://github.com/BestImageViewer/geeqie"
license=('GPL-2.0-or-later')
arch=('x86_64')

depends=(
  cfitsio
  djvulibre
  exiv2
  ffmpegthumbnailer
  gtk4
  imath
  libarchive
  libheif
  libraw
  libshumate
  libspelling
  lua
  openexr
  openjpeg2
  poppler-glib
)
makedepends=(
  evince
  git
  meson
)
checkdepends=(
  appstream
  markdownlint
  shellcheck
  xorg-server-xvfb
)
optdepends=(
  'fbida: for jpeg rotation' # exiftran
  'gawk: to use the geo-decode function'
  'gphoto2: command-line tools for various (plugin) operations'
  'imagemagick: command-line tools for various (plugin) operations'
  'perl-image-exiftool: for the jpeg extraction plugin'
)

provides=("$_pkgname")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=("$_pkgname"::"git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgsrc"
  local _version _revision _hash
  _version=$(git tag | grep -Ev '^.*[A-Za-z]{2}.*$' | sort -V | tail -1)
  _revision=$(git rev-list --count --cherry-pick $_version...HEAD)
  _hash=$(git rev-parse --short=7 HEAD)
  printf '%s.r%s.g%s' "${_version#v}" "${_revision:?}" "${_hash:?}"
}

build() {
  arch-meson "$_pkgsrc" build
  meson compile -C build
}

check() {
  dbus-run-session xvfb-run -s '-nolisten local' \
    meson test -C build --print-errorlogs
}

package() {
  if [[ "${_use_sodeps::1}" == "t" ]]; then
    eval "depends+=(
      libarchive.so
      libcairo.so
      libexiv2.so
      libgdk_pixbuf-2.0.so
      libgio-2.0.so
      libglib-2.0.so
      libgobject-2.0.so
      libgraphene-1.0.so
      libgtk-4.so
      libgtksourceview-5.so
      libheif.so
      libjpeg.so
      libjxl.so
      liblcms2.so
      libpango-1.0.so
      libpangocairo-1.0.so
      libpoppler-glib.so
      libshumate-1.0.so
      libspelling-1.so
      libtiff.so
      libwebp.so
    )"
  fi

  DESTDIR="$pkgdir" meson install -C build
}