PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30

# Maintainer: Antonin Décimo <antonin dot decimo at gmail dot com>
pkgname=generate-ipv6-address
pkgver=0.1
pkgrel=2
pkgdesc="Perform IPv6 address generation"
arch=('x86_64')
url="https://www.irif.fr/~jch/software/ahcp/ahcp-generate-address.html"
license=('MIT')
# Could not use the signature .asc file for some reason
source=("https://www.irif.fr/~jch/software/files/$pkgname-$pkgver.tar.gz")
sha256sums=('e1356d245d5f891fa39b796a8a2deefdaa89f08130dc97a378738ca5ed9a20fa')

build() {
	cd "$pkgname-$pkgver"
	make
}

package() {
	cd "$pkgname-$pkgver"

	sed -n '/Copyright/,/ SOFTWARE\./p' generate-ipv6-address.c > LICENSE
	sed -i 's/ahcp-generate-address/generate-ipv6-address/g' generate-ipv6-address.man

	mkdir -p "$pkgdir/usr/bin" \
	         "$pkgdir/usr/share/man/man8" \
	         "$pkgdir/usr/share/licenses/$pkgname"
	install -Dm755 generate-ipv6-address "$pkgdir/usr/bin/"
	install -Dm644 generate-ipv6-address.man "$pkgdir/usr/share/man/man8/generate-ipv6-address.8"
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}