blob: a9cb9f5607d85a67095c734f5a4eeb3c9ae4e53d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Adam Perkowski <adas1per@protonmail.com>
# https://github.com/adamperkowski/PKGBUILDs
pkgname=gengo
pkgver=0.12.2
pkgrel=1
pkgdesc='Linguist-inspired language classifier'
arch=('x86_64')
url="https://github.com/spenserblack/$pkgname"
license=('MIT' 'Apache-2.0')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('6707e79672bffa2754f4e952c4c490ee2a3f3002bc6b2c76f2aa90eae3111db6')
makedepends=('cargo' 'cmake' 'zlib')
depends=('gcc-libs' 'glibc')
options=('!lto')
prepare() {
cd "$pkgname-$pkgver"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd "$pkgname-$pkgver"
cargo build --release --frozen
}
# tests failing with:
# Error {
# kind: NoRepository,
# source: Some(NoGitRepository {
# path: "/build/gengo/src/gengo-0.12.1/gengo"
# })
# }
#check() {
# export RUSTUP_TOOLCHAIN=stable
# export CARGO_TARGET_DIR=target
# cd "$pkgname-$pkgver"
# cargo test
#}
package() {
cd "$pkgname-$pkgver"
install -Dm755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
install -Dm644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm644 LICENSE-APACHE -t "$pkgdir/usr/share/licenses/$pkgname"
}
# vim: ts=2 sw=2 et:
|