PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Maintainer: Zane Fernandes <zane.ferns360@gmail.com>
_pkgbasename=ghostty
pkgname=${_pkgbasename}-x86_64-v3-git
pkgrel=1
pkgver=r11113.d8e7a6634
pkgdesc="Fast, native, feature-rich terminal emulator with modern x86_64-v3 optimizations and bundled shell integration + terminfo"
arch=('x86_64')
url="https://github.com/ghostty-org/${_pkgbasename}"
provides=('ghostty')
conflicts=('ghostty' 'ghostty-git' 'ghostty-git-zen3')
license=('MIT')
depends=(bzip2
         fontconfig libfontconfig.so
         freetype2 libfreetype.so
         gcc-libs
         glibc
         glib2 libglib-2.0.so libgio-2.0.so libgobject-2.0.so
         gtk4 libgtk-4.so
         gtk4-layer-shell
         libx11
         harfbuzz libharfbuzz.so
         libadwaita libadwaita-1.so
         libpng
         oniguruma
         pixman
         wayland libwayland-client.so
         zlib)
makedepends=(blueprint-compiler
             git
             pandoc-cli
             zig)
source=("git+https://github.com/ghostty-org/${_pkgbasename}")
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}/${_pkgbasename}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "${srcdir}/${_pkgbasename}"
	ZIG_GLOBAL_CACHE_DIR="${srcdir}/tmp" ./nix/build-support/fetch-zig-cache.sh
	zig build \
		--system "${srcdir}/tmp/p" \
		-Dgtk-wayland=true \
		-Dgtk-x11=true \
		-Dpie=true \
		-Dcpu=x86_64_v3 \
		-Doptimize=ReleaseFast \
		-Demit-docs
}

package() {
	cd "${srcdir}/${_pkgbasename}"
	ZIG_GLOBAL_CACHE_DIR="${srcdir}/tmp" ./nix/build-support/fetch-zig-cache.sh
	DESTDIR="${pkgdir}" zig build install \
		--system "${srcdir}/tmp/p" \
		-Dgtk-wayland=true \
		-Dgtk-x11=true \
		-Dpie=true \
		-Dcpu=x86_64_v3 \
		-Doptimize=ReleaseFast \
		-Demit-docs

	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}