PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer:
# Contributor: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=git-lab-git
pkgver=r114.0556136
pkgrel=1
pkgdesc="Subcommand for git providing an arcanist-style interface to GitLab."
arch=('any')
url="https://invent.kde.org/jbbgameich/git-lab"
license=('GPL')
depends=('python-gitlab' 'python-gitpython')
makedepends=('git')
checkdepends=('python-pytest')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://invent.kde.org/jbbgameich/git-lab.git')
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir/${pkgname%-git}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$srcdir/${pkgname%-git}"
	python setup.py build
}

check() {
	cd "$srcdir/${pkgname%-git}"
	pytest
}

package() {
	cd "$srcdir/${pkgname%-git}"
	export PYTHONHASHSEED=0
	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
}