summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 580a169092b13c1a33b8dd4a04a9b9a519ed5dd8 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Philip Goto <philip.goto@gmail.com>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgname=gnome-contacts-git
pkgver=3.31.3.r14.g93ca1c6
pkgrel=1
pkgdesc="Contacts Manager for GNOME"
url="https://wiki.gnome.org/Apps/Contacts"
arch=(x86_64)
license=(GPL2)
depends=(gtk3 folks gnome-desktop dconf gnome-online-accounts libgee cheese libhandy)
makedepends=(vala gobject-introspection git meson libhandy)
groups=(gnome)
conflicts=(gnome-contacts)
provides=(gnome-contacts)
source=("git+https://gitlab.gnome.org/GNOME/gnome-contacts.git")
sha256sums=('SKIP')

pkgver() {
  cd gnome-contacts
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  arch-meson gnome-contacts build
  ninja -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}