blob: 0261a1d85cfd34fec7dfb84c92d71fd2d470b4ee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=gnome-network-displays
pkgver=0.92.1
pkgrel=1
pkgdesc="Miracast implementation for GNOME"
arch=('x86_64')
url="https://gitlab.gnome.org/GNOME/gnome-network-displays"
license=('GPL-3.0-or-later')
depends=(
'avahi'
'gst-plugins-bad'
'gst-plugins-good'
'gst-plugins-ugly'
'gst-rtsp-server'
'libadwaita'
'libportal-gtk4'
'libpulse'
'networkmanager'
'protobuf-c'
'python-gobject'
'xdg-desktop-portal'
)
makedepends=('meson')
optdepends=('dnsmasq' 'gst-plugin-pipewire' 'gstreamer-vaapi')
source=("$url/-/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('7b7949880d61e384ce4ec1deceedf94903298a462a7275cb1e894c370dc52241')
prepare() {
cd "$pkgname-$pkgver"
# https://gitlab.gnome.org/GNOME/gnome-network-displays/-/issues/272
sed -i -e "s/args: \['validate'/args: \['--nonet', 'validate'/" \
data/meson.build
}
build() {
arch-meson "$pkgname-$pkgver" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs || :
}
package() {
meson install -C build --destdir "$pkgdir"
}
|